Скрипты для системных администраторов Windows, Полезные скрипты для Win2003 Опции

[Nazim]

Предлагаю выкладывать сюда скрипты для администрирования. Например вот мой для подключения сетевого диска

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

Set WshNetwork = CreateObject("WScript.Network")
'Создание объекта типа Network Set Drives = WshNetwork.EnumNetworkDrives
c = 0 'Пременная проверки на наличие хотя бы одного сетевого диска!
i = 0 While i <= Drives.Count-1 'Проверка на наличие сетевых диков
c = 1 'MsgBox " У вас есть сетевой диск " & Drives.Item(i) & " - " & Drives.Item(i+1) i = i+2 Wend if c=0 then
'MsgBox "Нет ни одного подключенного диска"
'MsgBox "Попытка подключить сетевой диск" 'Set WshNetwork = CreateObject("WScript.Network")
WshNetwork.MapNetworkDrive "Z:", "\\Имясервера\имя папки"
End if

для подключения принтера

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

Set WshNetwork = WScript.CreateObject("WScript.Network")
WshNetwork.AddWindowsPrinterConnection "\\имяпринтсервера\имя принтера"

Меня например интересует скрипт, который отображает во сколько пользователь подключился в сеть.

Кстати кое что можно и тут найти

http://gallery.technet.microsoft.com/ScriptCenter/en-us/

Сообщение отредактировал Spectral - Apr 30 2011, 3:42

[klez]

Проверка изменений параметров в AD и отправка извещения на электронную почту или в список Sharepoint

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

/* ========================================================
'
' Script Information: Отправка сообщения администратору
' при изменении данных в AD возможна отправка сообщения
' на электронную почту или создание задачи в MOSS 2007
'
' Author: Коротенко Владимир SDC 2008 Voronezh
' Originally created: 15.04.2008 - 11:01:47
' Original path: untitled.vbs
' Description: Создание дампа схемы домена и сравнение
' с предыдущей копией для получения изменений и последующим
' оповещением
'
' ========================================================
*/




// Секция настроек скрипта
var SmtpHost,SmtpPort,MailSubject,MailTo,MailFrom,TextBody;
var DumpCmdLine,WinDiff,DumpFile,DumpFileOld,WorkingFolder;
var DiffFile,DiffMessage;
var SpListGuid,SpHost,UseSp;

SmtpHost = "comp1"; // почтовый сервер для отправки сообщений
SmtpPort = 25; // порт почтового сервера
MailSubject = "Внесите изменения в организационную диаграмму"; // заголовок сообщения письма
MailTo = "[email protected]"; // Адрес получателя
MailFrom = "[email protected]"; // Адрес отправителя
DumpCmdLine = "c:\\windows\\system32\\ldifde.exe"; // командная строка для дампа данных их AD
WinDiff = "c:\\temp\\windiff.exe"; // Программа для сравнения 2
DumpFile = "schema.ldf"; // Имя 1 файла для сохранения
DumpFileOld = "schemaOld.ldf"; // Имя 2 файла для сравнения
WorkingFolder = "c:\\temp\\"; // рабочая папка для временных файлов

DiffFile = "diff.log"; // Служебный файл для результатов сравнения
DiffMessage = "1 files listed"; // строка которую мы ищем при от личии файлов

SpListGuid = "{3D9B5EFB-C0C5-434C-B1DA-61FEA6E9D63B}";
SpHost = "http://portal4";
UseSp = true; // отправка сообщений в список Share Point

// Конец секции настроек

/*********************************************************************
Код изменять только в случае глубокого понимания для чего делаете
и главное КАК делаете !!!!!!!!!
**********************************************************************/

var file,wsh;
// создаем обьект для работы

file = WScript.CreateObject("Scripting.FileSystemObject");

if (file.FileExists ( WorkingFolder + DumpFileOld ))
file.DeleteFile( WorkingFolder + DumpFileOld);

if (file.FileExists(WorkingFolder + DumpFile) )
file.MoveFile (WorkingFolder + DumpFile, WorkingFolder + DumpFileOld)

wsh = WScript.CreateObject("WScript.Shell");

wsh.Run( DumpCmdLine + " -f " + WorkingFolder + DumpFile,1,1);
TrimUnused (WorkingFolder + DumpFile);

if (file.FileExists ( WorkingFolder + DumpFileOld ))
CheckChanges( WorkingFolder + DumpFile,WorkingFolder + DumpFileOld);




// Проверка на различие 2 файлов
function CheckChanges (pathFrom ,pathTo)
{
var cmd;
// WinDiff.Exe output.ldf schemaOld.ldf -Sx logcmd
cmd = WinDiff + " " + pathFrom + " " + pathTo + " -Sx " + WorkingFolder + DiffFile;
wsh.Run (cmd,1,1);
objFile = file.OpenTextFile(WorkingFolder + DiffFile,1);
var buff = new String();
buff = objFile.ReadAll();
objFile.Close();
var arr = new Array();
arr = buff.split("\r\n");

for(var i = 0; i<arr.length ; i++)
{
// Проверяем отличаются ли файлы, если так отправляем сообщение

if( arr[i].indexOf(DiffMessage) > - 1 )
{
var d = new Date();
TextBody = "Обнаружены изменения в схеме. Время сравнения: " + d.toString();
SendMessage();
}
}
}



// Убираем строки с часто изменяемыми аттрибутами
function TrimUnused (name )
{
var ForReading = 1;
var ForWriting = 2;
var objFSo,objFile;


objFSo = new ActiveXObject("Scripting.FileSystemObject");
objFile = objFSo.OpenTextFile(name, ForReading);
var strContents = new String();
strContents = objFile.ReadAll();
objFile.Close();

var arr = new Array();
arr = strContents.split("\r\n");

objFile = objFSo.OpenTextFile(name, ForWriting);

for(var i = 0; i < arr.length ; i++)
{
if( arr[i].indexOf("lastLogon" ) == -1 ){
objFile.WriteLine( arr[i]);
}
}
objFile.Close();
}



// Отправка сообщения по адресу все параметры должны быть заданы в секции глобальных переменных

function SendMessage(){

if (UseSp)
{
NewMessage( SpListGuid , SpHost , TextBody);
return;
}
var objEmail = new ActiveXObject( "CDO.Message" );
objEmail.From = MailFrom;
objEmail.To = MailTo;

objEmail.Subject = MailSubject;
objEmail.Textbody = TextBody;
objEmail.MimeFormatted = true;
objEmail.BodyPart.Charset="windows-1251";
objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2;
objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = SmtpHost;
objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = SmtpPort;
objEmail.Configuration.Fields.Update() ;
objEmail.Send();

}

// создаем новое сообщение в списке Sharepoint
function NewMessage (list,hostName,message)
{
var web,req,batch;
web = new ActiveXObject( "MSXML2.XMLHTTP.3.0" );

batch = "<Batch ListVersion='0' ><Method ID='1' Cmd='New'><Field Name='Title'>" + message + "</Field></Method></Batch>";

var req = "<?xml version='1.0' encoding='utf-8'?><soap:Envelope xmlns:xsi='http://www.w3.org/2001/XMLSchema-instance' xmlns:xsd='http://www.w3.org/2001/XMLSchema' xmlns:soap='http://schemas.xmlsoap.org/soap/envelope/'><soap:Body ><UpdateListItems xmlns='http://schemas.microsoft.com/sharepoint/soap/'>";
req += "<listName>" + list + "</listName>";
req += "<updates>" + batch + "</updates></UpdateListItems></soap:Body></soap:Envelope>";


var r = hostName + "/_vti_bin/Lists.asmx?op=UpdateListItems";
web.Open( "POST", r, False );
web.setRequestHeader( "Content-Type","text/xml; charset=utf-8" );
web.setRequestHeader ("SOAPAction","http://schemas.microsoft.com/sharepoint/soap/UpdateListItems");
web.send( req);

//'WScript.Echo req
//'WScript.Echo Chr (13) & Chr (10)
//'WScript.Echo web.responseText

}

Скрипт для удаления лицензии терминалов на клиентах, каждые 30 дней:

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

' Удаляет при необходимости раздел реестра, в котором хранятся временные лицензии, если прошло 30 дней.
Option Explicit
Dim iCount, dDat, dReadDat, strPath, strRegKey 'объявление переменных
Dim fso, fLogFile, wshSysEnv, wshShell 'объявление объектов

dDat = date 'получаем текущую дату
err.clear 'yf всякий случай чистим стэк ошибок

on error resume next 'После этого сообщения об ошибках не выводятся

'Создаём объект Shell
Set wshShell = WScript.CreateObject("WScript.Shell")
'Создаём объект Environment, в котором находятся искомая системная переменная
Set wshSysEnv = WshShell.Environment("PROCESS")
'Вытаскиваем системную переменную (путь к виндовской папке) и помещаем ее в строковую переменную для дальнейшего использования
strPath = wshSysEnv("WINDIR")

'Создаём объект доступа к файловой системе и объект доступа к нужному файлу на чтение
Set fso = CreateObject("Scripting.FileSystemObject")
set fLogFile = fso.OpenTextFile(strPath & "\LiDelDat.alx", 1, false)

'Основное условие удаления или неудаления ветви реестра
If err.number<>0 then
'Выполнение процедуры удаления ветви реестра
Call DelLicense

'Занесение последней даты удаления лицензии в файл журнала, затирая имеющуюся в нём запись
Call WriteToLog
Else
'Считываем из файла и сравниваем дату последнего удаления лицензии с текущей датой
dReadDat = CDate(fLogFile.ReadLine())

'Должно быть (dDat - dReadDat)
If (dDat - dReadDat) > 29 Then
'Выполнение процедуры удаления ветви реестра
Call DelLicense

'Занесение последней даты удаления лицензии в файл журнала, затирая имеющуюся в нём запись
Call WriteToLog
End If
End If

'Уничтожаем все ненужные более объекты
Set WshShell = Nothing
Set wshSysEnv = Nothing
Set fso = Nothing

'************************************************************
'Процедуры
'************************************************************
'Процедура удаления лицензии
Sub DelLicense()
'Удаляем лицензии-подключи по одной
on error resume next
err.clear

for iCount = 0 to 9
strRegKey = "HKLM\SOFTWARE\Microsoft\MSLicensing\Store\LICENSE00" & iCount & "\"
WshShell.RegDelete (strRegKey)

If err.number <> 0 then
err.clear
End If
next

'Удаляем подключи основного раздела
WshShell.RegDelete ("HKLM\SOFTWARE\Microsoft\MSLicensing\Store\")
if err.number <> 0 then err.clear

WshShell.RegDelete ("HKLM\SOFTWARE\Microsoft\MSLicensing\HardwareID\")
if err.number <> 0 then err.clear

'Удаляем основной раздел
WshShell.RegDelete ("HKLM\SOFTWARE\Microsoft\MSLicensing\")
if err.number <> 0 then err.clear

End Sub

'Процедура записи даты последнего удаления лицензии в файл
Sub WriteToLog()
err.clear

'Создаём объект доступа к нужному файлу на запись с затиранием предыдущих записей
set fLogFile = fso.OpenTextFile(strPath & "\LiDelDat.alx", 2, true)

'Записываем в файл дату очистки реестра
fLogFile.Write(Date)

set fLogFile = nothing 'уничтожаем объект
End Sub

Скрипт по борьбе с mail.ru-агентом

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

Const DeleteReadOnly = TRUE

Set WshShell = WScript.CreateObject ("Wscript.Shell")
Set WshSysEnv = WshShell.Environment ("Process")

Set objFSO = CreateObject("Scripting.FileSystemObject")
agentFile = WshSysEnv ("userprofile") + "\Application Data\Mail.Ru\Agent\magent.exe"


If objFSO.FileExists(agentFile) Then

objFSO.DeleteFile(agentFile), DeleteReadOnly


if err.number = 0 then
Set objEmail = CreateObject("CDO.Message")

objEmail.From = "[email protected]"
objEmail.To = "[email protected]"
objEmail.Subject = "Mail.ru-агент"
objEmail.Textbody = "Уважаемые господа системные администраторы, уведомляю Вас о том что уничтожен вражеский mail.ru агент из " + WshSysEnv ("userprofile")
objEmail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
objEmail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserver") = _
"ip почтового сервера"
objEmail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
objEmail.Configuration.Fields.Update
objEmail.Send

end if

end if

P.S. Еще нужно?

[Nazim]

Кстати вот есть также сайтик http://www.activexperts.com/activmonitor/w...t/adminscripts/

[Spyder3W]

если например с 1 поста могут использоватся то со 2 - неа

[olexande]

Наверно проще всего получать когда пользователь подключился - в батнике или логон скрипте:

echo. | date >> user_date.log

[klez]

Это скрипт делает backup системы и заливает его на фтп

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

strComputer = "."
Set WshShell = WScript.CreateObject("WScript.Shell")
strCommand = "C:\WINDOWS\system32\ntbackup.exe backup @C:\cmd\Back-UP-Drive-C.bks /a /v:no /r:no /rs:no /hc:off /m normal /j Back-UP-Drive-C /l:s /f D:\Back-Up\Backup-drive-c.bkf"
WshShell.Run strcommand, 1, true

Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_LocalTime")

For Each objItem in colItems
strCommand = "C:\Arch\7z.exe a D:\Back-Up\Backup-dc-srv-01-DayOf-Week-"&objItem.DayOfWeek&".7z D:\Back-Up\*.bkf -t7z -m0=BCJ2 -m1=LZMA:d23 -m2=LZMA:d19 -m3=LZMA:d10M -mb0:1 -mb0s1:2 -mb0s2:3"
Next
WshShell.Run strcommand, 1, true
strCommand = "ftp -s:C:\CMD\ctp-command.txt"
WshShell.Run strcommand, 1, true

[metalolom]

Это скрипт полезен в больших структурах где отдел кадров далеко от ИТ.
Скрипт блокирует/разблокировывает пользователей в AD, беря из определённого файла список их ФИО, и уведомляет администратора по почте о результатах.
Скрипт писался на коленке, здесь предоставлена лишь общая часть, некоторые моменты можно оптимизировать, но меня лично и так устраивает

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

Dim Mlogins(9000),MAdspath(9000),MFullName(9000)
Dim objFileSystem, objInputFileFromKardy,strData
Set objFSO = CreateObject("Scripting.FileSystemObject")
Const OPEN_FILE_FOR_READING = 1

'Указываем домен
Const strDomainName="<имя домена например domain.com>"
'Указываем OU в AD, внутри которой мы будем искать
Const strStartOU="Domain Users"
strDomainDN="DC="&Replace(strDomainName,".",",DC=")

'---------------------Получение данных--------------------
Set objConnection = CreateObject("ADODB.Connection")
objConnection.Open "Provider=ADsDSOObject;"
Set objCommand = CreateObject("ADODB.Command")
objCommand.ActiveConnection = objConnection
objCommand.CommandText = "<LDAP://OU="&strStartOU&","&strDomainDN&">;(&(objectCategory=person)(objectClass=user));ADsPath;subtree"
objCommand.Properties("Page Size")=4000

Set objRecordSet = objCommand.Execute


'------Индексирование --------
index=0
While Not objRecordset.EOF
strADsPath = objRecordset.Fields("ADsPath")
Set objUser = GetObject(strADsPath)
MFullName(index)=objUser.DisplayName&" "
Mlogins(index)=objUser.sAMAccountName
MAdspath(index)=strADsPath
index=index+1
objRecordset.MoveNext

Wend
objConnection.Close

index=index-1
maxindex=index

'Путь в файлу в котором хранится список ФИО людей учётные записи которых нужно открыть/закрыть
strFileOfFiried = "d:\file_of_firied.txt"

Set objFileSystem = CreateObject("Scripting.fileSystemObject")
Set objInputFileFromKardy = objFileSystem.OpenTextFile(strFileOfFiried,OPEN_FILE_FOR_READING)
'Загоняем содержимое файла в массив
inputDataFromFiried = Split(objInputFileFromKardy.ReadAll, vbNewline)
'Обнуляем списки результатов
UserDisables=""
UserUpdated=""
UserNoFound=""
UserDuplicated=""
ii=0


For each strFULL In inputDataFromFiried
if Len(strFULL)>5 then
'обнуляем счётчик найденых соответсвий
e=0
'1е поле:выделяем из строчки ФИО пользователя
strFIO=Left(strFULL,InStr(strFULL,";")-1)
'Разбиваем по частям ФИО
Familia=Left(strFIO,(Instr(strFIO," ")-1))
N=Trim(mid(strFIO,Instr(strFIO," ")))
Imya=Left(N,(Instr(N," ")-1))
Otchestvo=Trim(mid(N,Instr(N," ")))
'Собираем по частям ФИО
strFIO=Familia&" "&Imya&" "&Otchestvo

index=maxindex
While index>1

'Разбиваем по частям ФИО в AD

AdFamilia=""
AdImya=""
AdOtchestvo=""
AdFamilia=Left(MFullName(index),(Instr(MFullName(index)," ")-1))
if Len(Trim(mid(MFullName(index),Instr(MFullName(index)," "))))>1 then
AdN=Trim(mid(MFullName(index),Instr(MFullName(index)," ")))
if Len(Left(AdN,(Instr(AdN," "))))>1 then
AdImya=Left(AdN,(Instr(AdN," ")-1))
if Len(Trim(mid(AdN,Instr(AdN," "))))>1 then
AdOtchestvo=Trim(mid(AdN,Instr(AdN," ")))
end if
end if

end if


'Собираем по частям ФИО
AdstrFIO=AdFamilia&" "&AdImya&" "&AdOtchestvo
AdstrFIO1=AdImya&" "&AdOtchestvo&" "&AdFamilia
AdstrFIO2=AdImya&" "&AdFamilia&" "&AdOtchestvo
'Wscript.Echo AdstrFIO

if (StrFIO=AdstrFIO) or (StrFIO=AdstrFIO1) or (StrFIO=AdstrFIO2) then
e=e+1
Mindex=index
end if
index=index-1
Wend


if e=1 then
'блокируем логин в AD
LockUser(Mlogins(Mindex))
UserDisables=UserDisables& "User: " &strFIO&" is disabled" & vbCrLf
end if
'Не блокируем/открываем, т.к. у нас найдено несколько одинаковых ФИО
if e>1 then
UserNoFound=UserNoFound &"User: " &strFIO&" is found more than 1 times" & vbCrLf
end if
'Не блокируем/открываем, т.к. пользователь не найден
if e=0 then
UserDuplicated=UserDuplicated&"User: " &strFIO&" is not found " & vbCrLf
end if

end if


Next






'если есть какой-то результат, то
if (len(UserDisables)+len(UserNoFound)+len(UserDuplicated) > 10) then
' начинаем отправлять почту

Set objNetwork = CreateObject("Wscript.Network")
objComputerName = objNetwork.ComputerName
objUserName = objNetwork.UserName
Set objMessage = CreateObject("CDO.Message")
objMessage.From = "<e-mail от кого отправляется почта>"
objMessage.To = "<e-mail кому отправляется почта>"
objMessage.Subject = "Тема письма"

'Ставим кодировочку
objMessage.bodypart.charset= "koi8-r"
objMessage.TextBody = UserDisables&vbCrLf&UserNoFound&vbCrLf&UserDuplicated
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
'Name or IP of Remote SMTP Server
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "<адрес smtp сервера>"
'Server port (typically 25)
objMessage.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
objMessage.Configuration.Fields.Update
'==End remote SMTP server configuration section==

objMessage.Send


end if



objInputFileFromKardy.Close
Set objFileSystem = Nothing
Sub LockUser(strText)
' в этой строчке значение TRUE - дисейблит пользователя, FALSE - открывает пользователя
strDisableAccount = TRUE

strUserLogin = strText
set objUser = GetObject("WinNT://<домен>/"& strUserLogin &",user")


if strDisableAccount = TRUE then
objUser.AccountDisabled = strDisableAccount
objUser.Description = "Account is Disabled because of firing " & "at "&" "&Date()
objUser.SetInfo
end if

if strDisableAccount = FALSE then
objUser.AccountDisabled = strDisableAccount
objUser.Description = "Account is Opened by script " & "at "&" "&Date()
objUser.SetInfo
end if


End Sub

[Alex_GR]

Нужен скрипт для получения инфо по объектам АД - Пользователь (поиск по всему каталогу или конкретным OU ), у которых "Срок действия учетной записи: Истекает дд/мм/гггг"

Сообщение отредактировал Alex_GR - May 8 2008, 16:35

[Alex_GR]

Кстати вот есть также сайтик http://www.activexperts.com/activmonitor/w...t/adminscripts/

Как этими скриптами воспользоваться ?
Если не трудно напиши. спс.

[klez]

Этот скрипт предназначен для копирования файла в пользовательские перемещаемые профил

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

//*****************************************************************************
// JScript 2004 Shs
//Этот скрипт предназначен для копирования файла в пользовательские перемещаемые профили
//(Добавляем ярлычок в меню пользователя)
//******************************************************************************
//
//
//*****************************************************************************
// Рекурсивная функция перехода по всем подкаталогам, начиная с заданого (PolFldr)
// и копирования заданного файла (ScriptName) по заданым папкам (FldrName)
//******************************************************************************
function LoopSubFolders (PolFldr, DeepCount)
{
var SubFolders, // Коллекция подкатологов системных политик
fsoPolFldr, //объект для доступа к папке
CurFldr; //текущая папка

DeepCount++;
//WScript.Echo(DeepCount);
if (DeepCount<DeepLimit)
{
fsoPolFldr = FSO.GetFolder(PolFldr);
//Получаем коллекцию подкаталогов каталога системных политик
SubFolders = new Enumerator (fsoPolFldr.SubFolders);
//
for (;!SubFolders.atEnd();SubFolders.moveNext())
{
CurFldr = SubFolders.item();
if (CurFldr.Name == FldrName)
{
try {
WScript.Echo(CurFldr.Path+"\\"+ScriptName);
//WScript.Echo(Path2Scripts + "\\"+ ScriptName);
FSO.CopyFile(Path2Scripts + "\\"+ ScriptName,CurFldr.Path+"\\"+ScriptName,true)
}
catch (e)
{//обрабатываем возможные ошибки
var Msg;
if (e !=0) Msg="Error - "+e.description
else Msg="Ok";
WScript.Echo(Msg);
}
}
//рекурсивный вызов
LoopSubFolders (CurFldr,DeepCount);
}//end for
}//end if
}
//********************************************************************************

//
//


//********************************************************************************

//Заглушка
//********************************************************************************

//здесь будет код, получения из параметров командной строки
// 1)наименования расспространяемого файла
// 2)наименования каталога в каждом профиле, в который будет копироваться распространяемый файл
//********************************************************************************

var ScriptName = "Обновление рабочего меню.lnk",
FldrName = "Главное меню"; // Имя искомой подпапки в профиле (в нее будем копировать файл-ярлык)
//********************************************************************************
**




//********************************************************************************
*
//Объявляем глобальные переменные
//********************************************************************************
*
var FSO, // объект FileSystemObject
Path2Scripts, // Путь к распростроняемому файлу (предполагается, что файлы лежат в той же папке, что и этот файл)
DeepCount, //Счетчик глубины рекурсии
DeepLimit, //Ограничение глубины рекурсии
PolF; // Корень, с которого начинается поиск и распространение файлов по низлежащим папкам
//********************************************************************************
*
PolF = "\\\\DC\\UserFolders\\OZI"; ////
// Создаем объект FileSystemObject;
FSO = WScript.CreateObject("Scripting.FileSystemObject");
DeepCount=0;
Path2Scripts = FSO.GetParentFolderName(FSO.GetFile(WScript.ScriptFullName));
// Ограничение глубины рекурсивных вызовов
DeepLimit=4;
LoopSubFolders(PolF,DeepCount);

Ивентаризация всех машин в домене.

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

dim strclass, objAD, obj
dim invdate
dim constmb, constgb, sizegb
dim compname, temp, compad
constmb=1048576
constgb=1073741824
strclass = array( "win32_ComputerSystem", "win32_bios", "win32_processor",_
"win32_diskdrive", "win32_videocontroller", "win32_NetworkAdapter",_
"win32_sounddevice", "win32_SCSIController", "win32_printer")

set objAD=getobject("LDAP://CN=Computers,DC=aaa,DC=bbb,DC=ccc")
objAD.filter=array("computer")
on error resume next
for each obj in objAD
CompAD=right(obj.name, len(obj.name)-3)
invdate = date
temp="<html>"+chr(10)+"Дата сбора: " & invdate & "<table>"+chr(10)
compname=""
' on error resume next
set objWMIService = GetObject("winmgmts://"&CompAD&"/root\cimv2")
i=0
s=0
d=0
q=0
' sizegb=""
for a=0 to 8
Set colitems = objwmiservice.instancesof(strclass(a))
for each objitem in colitems
select case a
case 0
temp=temp+"<tr><td>"
temp=temp+"Имя компьютера"+"</td><td>"+objitem.name+ "</td>" + chr(10)
temp=temp+"</tr>"+chr(10)
temp=temp+"<tr><td>"
temp=temp+"Оперативная память"+"</td><td>"+cstr(round(objitem.totalphysicalmemory/constmb))+ " MB</td>" + chr(10)
temp=temp+"</tr>"+chr(10)
temp=temp+"<tr><td>"
temp=temp+"Модель компьютера"+"</td><td>"+objitem.model+ "</td>" + chr(10)
temp=temp+"</tr>"+chr(10)
compname=objitem.name
case 1
temp=temp+"<tr><td>"
temp=temp+"Материнская плата"+"</td><td>"+objitem.SMBIOSBIOSVersion+"</td>"+chr(10)
temp=temp+"</tr>"+chr(10)
temp=temp+"<tr><td>"
temp=temp+"BIOS"+"</td><td>" + objitem.caption+"</td>"+chr(10)+"<td>"+chr(10)+"</td>"
temp=temp+"</tr>"+chr(10)
case 2
s=s+1
temp=temp+"<tr>"+chr(10)+"<td>"
temp=temp+"Процессор"+cstr(s)+"</td>"+chr(10)+"<td>"+objitem.name+" Частота "+cstr(objitem.CurrentClockSpeed)+chr(10)+"</td>"
temp=temp+"</tr>"+chr(10)
case 3
i=i+1
temp=temp+"<tr>"+chr(10)+"<td>"
if objitem.size > 0 then ' = nill then
sizegb=cstr(round(objitem.size/constgb,2))
else
sizegb=cstr(0)
end if
temp=temp+"Жесткий диск "+cstr(i)+"</td>"+chr(10)+"<td>"+objitem.model + " " + sizegb + " GB</td>" + chr(10)
temp=temp+"</tr>"+chr(10)
case 4
temp=temp+"<tr>"+chr(10)+"<td>"
temp=temp+"Видеоконтролер"+"</td>"+chr(10)+"<td>"+objitem.caption+chr(10)+"</td>"
temp=temp+"</tr>"+chr(10)
case 5
if objitem.adaptertypeid=0 and objitem.netconnectionstatus=2 then
temp=temp+"<tr>"+chr(10)+"<td>"
temp=temp+"Сетевой адаптер"+"</td>"+chr(10)
temp=temp+"<td>"+objitem.name+chr(10)+"</td>"
temp=temp+"</tr>"+chr(10)
end if
case 6
temp=temp+"<tr>"+chr(10)+"<td>"
temp=temp+"Звуковая карта"+"</td>"+chr(10)
temp=temp+"<td>"+objitem.caption+chr(10)+"</td></tr>"+chr(10)
case 7
temp=temp+"<tr>"+chr(10)+"<td>"
temp=temp+"SCSI Адаптер"+"</td>"+chr(10)
temp=temp+"<td>"+objitem.manufacturer+" "+objitem.caption+chr(10)+"</td></tr>"+chr(10)
case 8
d=d+1
temp=temp+"<tr>"+chr(10)+"<td>"
temp=temp+"Принтер "+cstr(d)+"</td>"+chr(10)+"<td>"+objitem.name+chr(10)+"</td>"
temp=temp+"</tr>"+chr(10)
end select
next
next
'Заключительная часть
temp=temp+"</table></html>"
'Запись файла
Dim fso, tf
Set fso = CreateObject("Scripting.FileSystemObject")
Set tf = fso.CreateTextFile("\\servak\comp\"&compname&".htm", True)
tf.Write (temp)
tf.Close
next

[Nazim]

Как этими скриптами воспользоваться ? Если не трудно напиши. спс.

Открываеш блокнот, копируеш туда код и сохраняеш документ с расширением .vbs.
Далее если сеть без доменов копируеш этот файлик в автозагрузку каждому ПК. Если сеть с доменом, то создаеш груповую политику (в AD), где в параметрах автозагрузки вставляеш данный файл. Далее при подключении или перезагрузке учетной записи будет выполняться скрипт

[Alex_GR]

Открываеш блокнот, копируеш туда код и сохраняеш документ с расширением .vbs.
Далее если сеть без доменов копируеш этот файлик в автозагрузку каждому ПК. Если сеть с доменом, то создаеш груповую политику (в AD), где в параметрах автозагрузки вставляеш данный файл. Далее при подключении или перезагрузке учетной записи будет выполняться скрипт

ок.
есть два скрипта - разницы не вижу
1.Determining When an Account Expires
Returns the expiration date for a user account.

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

On Error Resume Next
Set objUser = GetObject _
("LDAP://cn=myerken,ou=management,dc=fabrikam,dc=com")

dtmAccountExpiration = objUser.AccountExpirationDate

If err.number = -2147467259 Or _
dtmAccountExpiration = "1/1/1970" Then
WScript.echo "No account expiration specified"
Else
WScript.echo "Account expiration:" & _
objUser.AccountExpirationDate
End If

2. Determining When a User Account Expires
Reports the date that the MyerKen Active Directory user account expires.

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

On Error Resume Next
Set objUser = GetObject _
("LDAP://cn=MyerKen,ou=Management,dc=NA,dc=fabrikam,dc=com")
dtmAccountExpiration = objUser.AccountExpirationDate

If Err.Number = -2147467259 Or dtmAccountExpiration = "1/1/1970" Then
WScript.Echo "No account expiration specified"
Else
WScript.Echo "Account expiration: " & objUser.AccountExpirationDate
End If

я их кинул в файлик VBS, подставил свои параметры и ...... не увидел результата.
просьба протестировать и отписаться.
проблема была в том, что онсмотрит по конкретной учетке, а весь OU не смотрит.

кто может скрипт подправить ??? Всем спс.

Сообщение отредактировал Alex_GR - May 8 2008, 16:40

[Nazim]

Пробовать правда времени нету, но попробую и так понять
Сеть у тебя какая?(домен или)
Проверяеш где? И что именно меняеш в скрипте (нужно ж указывать учетную запись, домен и прочее)?

[klez]

Cкрипт рекурсивно устанавливает всем пользователям домена атрибут "User must change password on next logon"

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

Dim strMyOU
Dim strMyDomain

Dim objOU, objUser
Dim strContainer, strLastUser

strMyOU = "argo"
strMyDomain = "DC=argo,DC=com"

sub recurs(ou)
strContainer = "OU="+ou+"," + strMyDomain
set objOU = GetObject("LDAP://" & strContainer )
For each objUser in objOU
strLastUser = objUser.Get ("name")
If objUser.Class="organizationalUnit" Then
recurs(strLastUser+", OU="+ou)
Elseif objUser.Class="user" Then
objUser.Put "pwdLastSet", 0
objUser.SetInfo
end if
next
end Sub

recurs strMyOU

WScript.Quit

P.S. Ддля корректной работы необходимо в переменной strMyDomain определить имя домена с точки зрения LDAP - т.е. все точки заменить на "DC=". Таким образом, домен argo.com превращается в DC=argo,DC=com в переменную strMyOU необходимо поместить наименование Organization Unit а, юзеров которого необходимо подвергнуть процедуре изменения пароля.

[metalolom]

я их кинул в файлик VBS, подставил свои параметры и ...... не увидел результата.
просьба протестировать и отписаться.
проблема была в том, что онсмотрит по конкретной учетке, а весь OU не смотрит.

кто может скрипт подправить ??? Всем спс.

Например так:

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

'Указываем домен
Const strDomainName="<имя домена например domain.com>"
'Указываем OU в AD, внутри которой мы будем искать
Const strStartOU="Domain Users"
strDomainDN="DC="&Replace(strDomainName,".",",DC=")

'---------------------Получение данных--------------------
Set objConnection = CreateObject("ADODB.Connection")
objConnection.Open "Provider=ADsDSOObject;"
Set objCommand = CreateObject("ADODB.Command")
objCommand.ActiveConnection = objConnection
objCommand.CommandText = "<LDAP://OU="&strStartOU&","&strDomainDN&">;(&(objectCategory=person)(objectClass=user));ADsPath;subtree"
objCommand.Properties("Page Size")=9000

Set objRecordSet = objCommand.Execute


'------Индексирование --------
While Not objRecordset.EOF
strADsPath = objRecordset.Fields("ADsPath")
Set objUser = GetObject(strADsPath)

dtmAccountExpiration = objUser.AccountExpirationDate
If err.number = -2147467259 Or _
dtmAccountExpiration = "1/1/1970" Then
WScript.echo "No account expiration specified"
Else
WScript.echo "Account expiration:" & _
objUser.AccountExpirationDate

objRecordset.MoveNext

End If



Wend
objConnection.Close

[metalolom]

Предлагаю тему закрепить.

[klez]

Получение SID (а) компьютера из AD

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

On Error Resume Next
Dim Tmp, x, b, Sid
Set objSysInfo = CreateObject("ADSystemInfo")
strComputerDN = objSysInfo.ComputerName
Set objCmp = GetObject("LDAP://" & strComputerDN)
Sid = objCmp.objectSID
gSID = "S-1-5-"&Convert(16,19)&"-"&Convert(12,15)&"-"&Convert(8,11)&"-"&Convert(4,7)&"-"&Convert(0,3)
Set objGroup = Nothing

function Convert(u,l)
Tmp = ""
For x = UBound(Sid)-u to UBound(Sid)-l Step -1
b = AscB(MidB(SID, x + 1))
Tmp = Tmp & Hex(b \ 16) & Hex(b And 15)
Next
Convert = Clng("&H" & Tmp)
end function
wscript.echo(gSID)

Поиск аккаунтов в ActiveDirectory с просроченными паролями

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

on Error resume next

DC=getObject("LDAP://RootDSE").get("defaultNamingContext")
dom=getObject("LDAP://" & DC).get("Name")
pwAge=getObject("WinNT://" & dom).get("MaxPasswordAge")/86400

set objConnection=createObject("ADODB.Connection")
objConnection.open "Provider=ADsDSOObject;"

set objCmd=createObject("ADODB.Command")
objCmd.ActiveConnection=objConnection

' -- Command for searching computer accounts
'cmd="<LDAP://" & DC & ">;(objectClass=computer);distinguishedName,samAccountName;subtree"

' -- Command for searching user accounts
cmd="<LDAP://" & DC & ">;(objectCategory=person);distinguishedName,samAccountName;subtree"

objCmd.CommandText=cmd

set col=objCmd.execute

if col.recordCount>0 then
col.moveFirst
while not col.EOF
dn=col.fields(0).value
acc=col.fields(1).value

set obj=getObject("LDAP://" & dn)
accCtrl=obj.get("userAccountControl")

if (accCtrl and &h10000)=0 then
pwChg=obj.PasswordLastChanged
if (Err.Number<>0) then
E=CStr(Err.Number) & " " & Err.Description
' WScript.echo acc & space(16-len(acc)) & " - Error : " & E
Err.clear
else
if (now-pwChg)>pwAge then
WScript.echo acc & space(16-len(acc)) & " - Expired : " & (pwChg+pwAge)
else
' WScript.echo acc & space(16-len(acc)) & " - Expire on : " & (pwChg+pwAge)
end if
end if
else
' WScript.echo acc & space(16-len(acc)) & " - Never Expire"
end if
col.moveNext
wend
end If

objConnection.close

Если NetBIOS имя домена отличается от DNS до первой точки, то руками вместо строки
dom=getObject("LDAP://" & DC).get("Name") присвоить нужное значение

[Alex_GR]

Например так:

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

'Указываем домен
Const strDomainName="<имя домена например domain.com>"
'Указываем OU в AD, внутри которой мы будем искать
Const strStartOU="Domain Users"
strDomainDN="DC="&Replace(strDomainName,".",",DC=")

'---------------------Получение данных--------------------
Set objConnection = CreateObject("ADODB.Connection")
objConnection.Open "Provider=ADsDSOObject;"
Set objCommand = CreateObject("ADODB.Command")
objCommand.ActiveConnection = objConnection
objCommand.CommandText = "<LDAP://OU="&strStartOU&","&strDomainDN&">;(&(objectCategory=person)(objectClass=user));ADsPath;subtree"
objCommand.Properties("Page Size")=9000

Set objRecordSet = objCommand.Execute
'------Индексирование --------
While Not objRecordset.EOF
strADsPath = objRecordset.Fields("ADsPath")
Set objUser = GetObject(strADsPath)

dtmAccountExpiration = objUser.AccountExpirationDate
If err.number = -2147467259 Or _
dtmAccountExpiration = "1/1/1970" Then
WScript.echo "No account expiration specified"
Else
WScript.echo "Account expiration:" & _
objUser.AccountExpirationDate

objRecordset.MoveNext

End If
Wend
objConnection.Close

очень удачный "например".
только есть два "НО" - скрипт не показывает ФОИ и не совсем получилось с OU (у меня путь длиннее чем один юнит).
и вопрос: поиск внутри OU только пользователей? а если внутри есть ещё OU ? - смотрит все
с этим я разобрался.
Как сделать, чтобы скрипт смотрел только те учетки у которых в будущем закончится скор действия ??
ну и вывод в файл.
спс огромное

Сообщение отредактировал Alex_GR - May 12 2008, 13:58

[klez]

Скрипт опрашивает компьютеры домена на предмет того, какой пользователь залогинен в данный момент на каждом компьютере

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

On Error Resume Next

Const ADS_SCOPE_SUBTREE = 2

Set objRoot = GetObject("LDAP://RootDSE")
strDomainName = objRoot.Get("DefaultNamingContext")
Set objRoot = Nothing

strComputer = ""
Dim fso
Dim file

Set fso = CreateObject("Scripting.FileSystemObject")
Set file = fso.OpenTextFile ("logged_user_list.txt", 2, True)
Set objShell = CreateObject("WScript.Shell")

Set objConnection = CreateObject("ADODB.Connection")
Set objCommand = CreateObject("ADODB.Command")
objConnection.Provider = "ADsDSOObject"
objConnection.Open "Active Directory Provider"

Set objCommand.ActiveConnection = objConnection
objCommand.CommandText = "Select Name, Location from 'LDAP://" & strDomainName & "'" _
& "Where objectClass ='computer'"
objCommand.Properties("Page Size") = 1000
objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE
Set objRecordSet = objCommand.Execute

'****************************************************************************
******

objRecordSet.MoveFirst

Wscript.Echo "Processing information. This might take several minutes."

Do Until objRecordSet.EOF
strComputer = objRecordSet.Fields("Name").Value

' Проверяем доступность компьютера с помощью команды PING
' и анализа выходного потока

Set objScriptExec = objShell.Exec("%comspec% /c ping.exe -n 1 " & strComputer)
strPingResults = LCase(objScriptExec.StdOut.ReadAll)

' Если компьютер отвечает, подключаемся к его WMI

If InStr(strPingResults, "ttl=") Then
Set objWMIService = GetObject("winmgmts:" _
& "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")

Set colComputer = objWMIService.ExecQuery _
("Select * from Win32_ComputerSystem")

' Выводим список залогиненных пользователей в файл и на экран

For Each objComputer in colComputer
Wscript.Echo "Logged-on " &strComputer & " user: " & objComputer.UserName
file.WriteLine("Logged-on " &strComputer & " user: " & objComputer.UserName)
Next
objRecordSet.MoveNext

' Если компьютер не отвечает - выводим сообщение и перемещаемся к следующему

Else
WScript.Echo(strComputer & ": Не отвечает...")
objRecordSet.MoveNext
End If
Loop

Этот скрипт просматривает системный журнал Безопасность и если обнаружит в нём запись об изменении настроек браузера, то уведомит об этом.

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

On Error Resume Next
strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
& "{"{impersonationLevel=impersonate,(Security)}!\\" & strComputer & _
"\root\cimv2")
Set colMonitoredEvents = objWMIService.ExecNotificationQuery _
("SELECT * FROM __InstanceCreationEvent WHERE TargetInstance ISA " _
& "'Win32_NTLogEvent' AND TargetInstance.EventCode = '560' AND " _
& "TargetInstance.Logfile = 'Security' GROUP WITHIN 2")
Do
Set objLatestEvent = colMonitoredEvents.NextEvent
strAlertToSend = "Internet Explorer security settings have been " & _
"changed."
Wscript.Echo strAlertToSend
Loop

[metalolom]

очень удачный "например".
только есть два "НО" - скрипт не показывает ФОИ и не совсем получилось с OU (у меня путь длиннее чем один юнит).

Например печатеть свойство DisplayName, в скрпите ниже оно будет.
Насчёт OU в скрипте есть строчка запроса к LDAP:
objCommand.CommandText = "<LDAP://OU="&strStartOU&","&strDomainDN&">;(&(objectCategory=person)(objectClass=user));ADsPath;subtree"

из чего видно что в переменную strStartOU ты записываешь нужный тебе путь кроме первой "OU="

Как сделать, чтобы скрипт смотрел только те учетки у которых в будущем закончится скор действия ??

для вывода в файл запусти скрипт так:

Cscript.exe \Имя скрипта\ >  \путь и имя файла куда тебе нужно вывести данные\

Например:

Cscript.exe script.vbs > c:\expiration.log

В этом же скрипте за дату отвечает свойство:
dtmAccountExpiration сравниваешь его с нужной тебе датой и получаешь только тебу у кого дата истечения такая, как тебе надо.
Вот "доделаный например":)

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

'Указываем домен
Const strDomainName="<имя домена например domain.com>"
'Указываем OU в AD, внутри которой мы будем искать
Const strStartOU="Domain Users"
strDomainDN="DC="&Replace(strDomainName,".",",DC=")

'---------------------Получение данных--------------------
Set objConnection = CreateObject("ADODB.Connection")
objConnection.Open "Provider=ADsDSOObject;"
Set objCommand = CreateObject("ADODB.Command")
objCommand.ActiveConnection = objConnection
objCommand.CommandText = "<LDAP://OU="&strStartOU&","&strDomainDN&">;(&(objectCategory=person)(objectClass=user));ADsPath;subtree"
objCommand.Properties("Page Size")=9000

Set objRecordSet = objCommand.Execute

'------Индексирование --------
While Not objRecordset.EOF
strADsPath = objRecordset.Fields("ADsPath")
Set objUser = GetObject(strADsPath)

dtmAccountExpiration = objUser.AccountExpirationDate
If dtmAccountExpiration > "01.02.1970" Then
WScript.echo "We will have expriration at "&dtmAccountExpiration&" for user "&objUser.DisplayName

End If
objRecordset.MoveNext


Wend
objConnection.Close