Скрипты для системных администраторов Windows, Полезные скрипты для Win2003 Опции

[klez]

Скрипт ищет по всем контроллерам пользователей, которые не логинились уже более 90 дней и дизейблит их. После чего скидывает в файл их имена в форме Distinguished Name:

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

Dim objRootDSE, strConfig, adoConnection, adoCommand, strQuery
Dim adoRecordset, objDC
Dim strDNSDomain, objShell, lngBiasKey, lngBias, k, arrstrDCs()
Dim strDN, dtmDate, objDate, lngDate, objList, strUser
Dim strBase, strFilter, strAttributes, lngHigh, lngLow
Dim intUAC, objCurrentUser

' Использование объектов словаря чтоб потом узнать последние логоны пользователя.
Set objList = CreateObject("Scripting.Dictionary")
objList.CompareMode = vbTextCompare

' Получение местного времени с реестра.
Set objShell = CreateObject("Wscript.Shell")
lngBiasKey = objShell.RegRead("HKLM\System\CurrentControlSet\Control\" _
& "TimeZoneInformation\ActiveTimeBias")
If (UCase(TypeName(lngBiasKey)) = "LONG") Then
lngBias = lngBiasKey
ElseIf (UCase(TypeName(lngBiasKey)) = "VARIANT()") Then
lngBias = 0
For k = 0 To UBound(lngBiasKey)
lngBias = lngBias + (lngBiasKey(k) * 256^k)
Next
End If

' Получение конфигурациы и доменов из объектов RootDSE.
Set objRootDSE = GetObject("LDAP://RootDSE")
strConfig = objRootDSE.Get("configurationNamingContext")
strDNSDomain = objRootDSE.Get("defaultNamingContext")

' Использование ADO чтобы искать в Active Directory ObjectClass nTDSDSA.
Set adoCommand = CreateObject("ADODB.Command")
Set adoConnection = CreateObject("ADODB.Connection")
adoConnection.Provider = "ADsDSOObject"
adoConnection.Open "Active Directory Provider"
adoCommand.ActiveConnection = adoConnection

strBase = "<LDAP://" & strConfig & ">"
strFilter = "(objectClass=nTDSDSA)"
strAttributes = "AdsPath"
strQuery = strBase & ";" & strFilter & ";" & strAttributes & ";subtree"

adoCommand.CommandText = strQuery
adoCommand.Properties("Page Size") = 100
adoCommand.Properties("Timeout") = 60
adoCommand.Properties("Cache Results") = False

Set adoRecordset = adoCommand.Execute


k = 0
Do Until adoRecordset.EOF
Set objDC = _
GetObject(GetObject(adoRecordset.Fields("AdsPath")).Parent)
ReDim Preserve arrstrDCs(k)
arrstrDCs(k) = objDC.DNSHostName
k = k + 1
adoRecordset.MoveNext
Loop
adoRecordset.Close

' Получение атрибута последнего логона для каждого пользователя в контроллерах домена.
For k = 0 To Ubound(arrstrDCs)
strBase = "<LDAP://" & arrstrDCs(k) & "/" & strDNSDomain & ">"
strFilter = "(&(objectCategory=person)(objectClass=user))"
strAttributes = "distinguishedName,lastLogon"
strQuery = strBase & ";" & strFilter & ";" & strAttributes _
& ";subtree"
adoCommand.CommandText = strQuery
On Error Resume Next
Set adoRecordset = adoCommand.Execute
If (Err.Number <> 0) Then
On Error GoTo 0
Wscript.Echo "Контроллер домена MGSM.RU не найден: " & arrstrDCs(k)
Else
On Error GoTo 0
Do Until adoRecordset.EOF
strDN = adoRecordset.Fields("distinguishedName")
lngDate = adoRecordset.Fields("lastLogon")
On Error Resume Next
Set objDate = lngDate
If (Err.Number <> 0) Then
On Error GoTo 0
dtmDate = #1/1/1601#
Else
On Error GoTo 0
lngHigh = objDate.HighPart
lngLow = objDate.LowPart
If (lngLow < 0) Then
lngHigh = lngHigh + 1
End If
If (lngHigh = 0) And (lngLow = 0 ) Then
dtmDate = #1/1/1601#
Else
dtmDate = #1/1/1601# + (((lngHigh * (2 ^ 32)) _
+ lngLow)/600000000 - lngBias)/1440
End If
End If
If (objList.Exists(strDN) = True) Then
If (dtmDate > objList(strDN)) Then
objList.Item(strDN) = dtmDate
End If
Else
objList.Add strDN, dtmDate
End If
adoRecordset.MoveNext
Loop
adoRecordset.Close
End If
Next

' Создание логов
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objScriptFile = objFSO.OpenTextFile("c:\scripts\Account_lockout.vbs", _
ForReading)
Set objCommentFile = objFSO.OpenTextFile("c:\scripts\Lockedout_users.txt", _
ForWriting, TRUE)

'Сравнение дат

dblCurrentdate = Cdbl(date)
Const ADS_UF_ACCOUNTDISABLE = 2
Const ForReading = 1
Const ForWriting = 2

For Each strUser In objList.Keys

dblUserdate = Cdbl(objList.Item(strUser))

If (dblCurrentdate - dblUserdate > 90) Then



Set objCurrentUser = GetObject ("LDAP://" & strUser & "")
intUAC = objCurrentUser.Get("userAccountControl")

objCurrentUser.Put "userAccountControl", intUAC OR ADS_UF_ACCOUNTDISABLE
objCurrentUser.SetInfo

objCommentFile.Write strUser & VbCrLf

' Wscript.Echo strUser & " заблокирован"



Else

' Wscript.Echo strUser & " недавно логинился"



End if


Next

'Закрытие логов
objScriptFile.Close
objCommentFile.Close


' Очистка.
adoConnection.Close
Set objRootDSE = Nothing
Set adoConnection = Nothing
Set adoCommand = Nothing
Set adoRecordset = Nothing
Set objDC = Nothing
Set objDate = Nothing
Set objList = Nothing
Set objShell = Nothing
Set objCurrentUser = Nothing

[3in]

командный файл (closefl.bat ) закрывает все файлы, открытые пользователями в сети на вашем компьютере

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

if exist d:\files.txt del d:\files.txt
net file > d:\files.txt
for /f "skip=5 tokens=1" %%i in (d:\files.txt) do net file %%i /close
del d:\files.txt

[pekshin]

А есть ли скрипт, для разблокировки компа после определенного времени простоя компа заблокированым?

[Alex_GR]

1. Скрипт для уведомления пользователя об окончании действия учетки в домене за 10 дней (параметр можно изменить в 27 строке - dtmDaysToExpire > 10 ).
Бросать в логон.
В 5-й и 7-й строке подставить свои значения для домена и подразделения.

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

' Script name: WarnUserAboutAccountExpiration.vbs
' Created by Alex_GR - 26/05/2008

'Указываем домен
Const strDomainName="domen.com"
'Указываем OU в AD, внутри которой мы будем искать
Const strStartOU="Domain Users"
strDomainDN="DC="&Replace(strDomainName,".",",DC=")

On Error Resume Next
'Option Explicit
Dim strUserName, oNetwork, aConnection, aCommand, aResult, strDN, dtmAccountExpiration, dtmDaysToExpire, oShell
Set oNetwork = CreateObject("Wscript.network")
Set oShell = CreateObject("Wscript.shell")
strUserName = oNetwork.UserName
Set aConnection = CreateObject("ADODB.Connection")
Set aCommand = CreateObject("ADODB.Command")
aConnection.Provider = "ADsDSOObject"
aConnection.Open
aCommand.ActiveConnection = aConnection
aCommand.CommandText="<LDAP://OU="&strStartOU&","&strDomainDN&">;(&(objectCategory=User)(samAccountName=" & strUserName & "));distinguishedName;subTree"
Set aResult = aCommand.Execute()
strDN = aResult.Fields("distinguishedName")
Set objUser = GetObject("LDAP://" & strDN)
dtmAccountExpiration = objUser.AccountExpirationDate
dtmDaysToExpire = DateDiff("d", Now, dtmAccountExpiration)
If Err.Number = -2147467259 Or dtmAccountExpiration = "1/1/1970" Or dtmAccountExpiration = "01/01/1601 03:00:00" Or dtmAccountExpiration = "01.01.1601 03:00:00" Or dtmAccountExpiration = "1.1.1970" Or dtmDaysToExpire > 10 Then
' Можно выводить другое сообщение, если найдено соответствие условию
' MsgBox "Всe good "
Else
oShell.Popup "До окончания испытательного срока осталось " & dtmDaysToExpire & " дней!" & vbCrLf & _
"Учётная запись действительна до " & dtmAccountExpiration & vbCrLf & _
"Просьба об этом уведомить Вашего руководителя.", 60, "Уведомление от ИТ Департамента", 48+0
End If

2. Скрипт для поиска в активном каталоге пользователей с ограниченым сроком действия учётки и экспорта в файл.
В 5-й и 7-й строке подставить свои значения для домена и подразделения.

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

' Script name: UserAccountExpirationDate.vbs
' Created by Alex_GR - 12/05/2008

'Указываем домен
Const strDomainName="domen.com"
'Указываем OU в AD, внутри которой мы будем искать
Const strStartOU="Domain Users"
strDomainDN="DC="&Replace(strDomainName,".",",DC=")

---------------------Получение данных--------------------
Set objConnection = CreateObject("ADODB.Connection")
objConnection.Open "Provider=ADsDSOObject;"
Set objCommand = CreateObject("ADODB.Command")
objCommand.ActiveConnection = objConnection
objCommand.CommandText = "<LDAP://OU="&strStartOU&","&strDomainDN&">;(&(objectCategory=person)(objectClass=user));ADsPath;subtree"
objCommand.Properties("Page Size")=9000

Set objRecordSet = objCommand.Execute

Const ForAppending = 2
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile ("c:\UserAccountExpirationDate.txt", ForAppending, True)

'------Индексирование --------
While Not objRecordset.EOF
strADsPath = objRecordset.Fields("ADsPath")
Set objUser = GetObject(strADsPath)

dtmAccountExpiration = objUser.AccountExpirationDate

If err.number = -2147467259 Or dtmAccountExpiration = "01/01/1970" Or dtmAccountExpiration = "01/01/1601 03:00:00" Or dtmAccountExpiration = "01.01.1601 03:00:00" Or dtmAccountExpiration = "01.01.1970" Then
'Вывод сообщением
'WScript.echo ""

'запись в файл пустого значения
objTextFile.Write ""
objRecordset.MoveNext

Else
'Вывод сообщением
' WScript.echo objUser.displayName & " - учётка действительна до: " & objUser.AccountExpirationDate

'Запись в файл
objTextFile.WriteLine objUser.displayName & " - учётка действительна до: " & objUser.AccountExpirationDate
objRecordset.MoveNext
End If

Wend
objConnection.Close
WScript.echo "Экспорт закончен, файл создан - C:\UserAccountExpirationDate.txt"

3. Справочник по VBS в вормате CHM.

http://upload.com.ua/direct/900261120/scri...ository_1_1.chm

Сообщение отредактировал Alex_GR - May 28 2008, 14:28

[Nazim]

Может кто знает, кто встречал - нужен скрипт рассылки сообщений типа сохраните все данные. Конкретно для ситуации нужно вырубить файлсервер, так чтобы не бегать по офису а просто запустить скриптик. Знаю что можно с командной строки воспользоваться командой net send , но это чуток не то. Кто что скажет?

[olexande]

Может кто знает, кто встречал - нужен скрипт рассылки сообщений типа сохраните все данные. Конкретно для ситуации нужно вырубить файлсервер, так чтобы не бегать по офису а просто запустить скриптик. Знаю что можно с командной строки воспользоваться командой net send , но это чуток не то. Кто что скажет?

У себя в сети распространил внутренний чат, где делаю срочные объявления ...

net send может и на группы/домены делать рассылку ...
правда на компах обычно последнее время эта служба останавливается ...

[Fanta]

P.S. Еще нужно?

Так.
В кого є скрипт який би робив те що написано в цій темі ??

[klez]

Такого скрипта не встречал.
Но думаю что если это делать действительно автоматически, то без расширения схемы AD, тут не обойтись.IMHO

[Fanta]

Такого скрипта не встречал.
Но думаю что если это делать действительно автоматически, то без расширения схемы AD, тут не обойтись.IMHO

Скрипт який перевіряеє нових юзерів і відсилає ім лист з вказаним текстом
(переверяє з тією ж періодичністю з якою виконуеться скрипт тобто та яка вказана в Scheduled Tasks)

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

'Created by Mike Ruman 8/13/05
'Sends an email to accounts created today.

Dim StrDate, CurrentUTC
  
'Create the current date and time stamp for query for day before last
CurrentUTC = DatePart("yyyy", Date)
'now add Month in mm if only M add leading 0
if DatePart("m" , Now) < 10 then
   CurrentUTC = CurrentUTC & 0 & DatePart("m" , Now)
  else
   CurrentUTC = CurrentUTC & DatePart("m" , Now)
end if
'now add Day in dd if only d add leading 0
if DatePart("d" , Now) < 10 then
'OPTIONAL - FOR MANY DAYS, replace line below with CurrentUTC = CurrentUTC & 0 & DatePart("d" , Now - X)  where X = # of days

   CurrentUTC = CurrentUTC & 0 & DatePart("d" , Now)
  else
'OPTIONAL - FOR MANY DAYS, replace line below with CurrentUTC = CurrentUTC & DatePart("d" , Now - X)  where X = # of days
   CurrentUTC = CurrentUTC & DatePart("d" , Now)
end if
' Tag hour, minute, second on
strDate = CurrentUTC&"000001.0Z"
  
'Create AD Connection
Set oConnection1 = CreateObject("ADODB.Connection")
Set oCommand1 = CreateObject("ADODB.Command")
oConnection1.Provider = "ADsDSOObject"  ' This is the ADSI OLE-DB provider name
oConnection1.Open "Active Directory Provider"
' Create a command object for this connection.
Set oCommand1.ActiveConnection = oConnection1
'Set Query definition
' тут задаем доменные параметры берем из AD
oCommand1.CommandText = "select mail from 'LDAP://DC=it, DC=local' WHERE objectCategory='Person' AND objectClass='user'AND msExchHideFromAddressLists<>'True' AND whenCreated>='" & strDate & "'"

oCommand1.Properties("Page Size") = 30000
' Execute the query.
Set rs = oCommand1.Execute
  

rs.movefirst
'Create the loop of results
Do Until rs.EOF = True

  
'Create Email
' настройки письма для пользователя
Set objEmail = CreateObject("CDO.Message")
objEmail.From = "[email protected]"
objEmail.To = rs.Fields("mail")
'Optional BCC field
'objEmail.BCC = "[email protected]"
objEmail.Subject = "A welcome message from Exchange"
objEmail.HTMLbody = "Добро пожаловать в ........."
  
objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/languagecode") = 1049
'objMessage.BodyPart.CharSet = "windows-1251".
objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/usemessageresponsetext") = true


'Optional Add an attachment
'objEmail.AddAttachment "C:\new_hire_audio_message.wav"

objEmail.Configuration.Fields.Item _
    ("http://schemas.microsoft.com/cdo/configuration/sendusing  ") = 2
objEmail.Configuration.Fields.Item _
    ("http://schemas.microsoft.com/cdo/configuration/smtpserver  ") = _
        "ExchangeServer" 'Replace ExchangeServer with server IP or name
objEmail.Configuration.Fields.Item _
    ("http://schemas.microsoft.com/cdo/configuration/smtpserverport  ") = 25
objEmail.Configuration.Fields.Update
  
'Optional - Read the message before it's sent
'MsgBox objEmail.GetStream.ReadText
objEmail.Send
rs.movenext
Loop
  
'Close AD Connection
oConnection1.close

лише одна трабла - мені не вдалося подружити його з кирилицею

Буду дуже вдячний якщо хтось пофіксить це!

[Alex_GR]

Скрипт який перевіряеє нових юзерів і відсилає ім лист з вказаним текстом
(переверяє з тією ж періодичністю з якою виконуеться скрипт тобто та яка вказана в Scheduled Tasks)

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

'Created by Mike Ruman 8/13/05
'Sends an email to accounts created today.

Dim StrDate, CurrentUTC
  
'Create the current date and time stamp for query for day before last
CurrentUTC = DatePart("yyyy", Date)
'now add Month in mm if only M add leading 0
if DatePart("m" , Now) < 10 then
   CurrentUTC = CurrentUTC & 0 & DatePart("m" , Now)
  else
   CurrentUTC = CurrentUTC & DatePart("m" , Now)
end if
'now add Day in dd if only d add leading 0
if DatePart("d" , Now) < 10 then
'OPTIONAL - FOR MANY DAYS, replace line below with CurrentUTC = CurrentUTC & 0 & DatePart("d" , Now - X)  where X = # of days

   CurrentUTC = CurrentUTC & 0 & DatePart("d" , Now)
  else
'OPTIONAL - FOR MANY DAYS, replace line below with CurrentUTC = CurrentUTC & DatePart("d" , Now - X)  where X = # of days
   CurrentUTC = CurrentUTC & DatePart("d" , Now)
end if
' Tag hour, minute, second on
strDate = CurrentUTC&"000001.0Z"
  
'Create AD Connection
Set oConnection1 = CreateObject("ADODB.Connection")
Set oCommand1 = CreateObject("ADODB.Command")
oConnection1.Provider = "ADsDSOObject"  ' This is the ADSI OLE-DB provider name
oConnection1.Open "Active Directory Provider"
' Create a command object for this connection.
Set oCommand1.ActiveConnection = oConnection1
'Set Query definition
' тут задаем доменные параметры берем из AD
oCommand1.CommandText = "select mail from 'LDAP://DC=it, DC=local' WHERE objectCategory='Person' AND objectClass='user'AND msExchHideFromAddressLists<>'True' AND whenCreated>='" & strDate & "'"

oCommand1.Properties("Page Size") = 30000
' Execute the query.
Set rs = oCommand1.Execute
  

rs.movefirst
'Create the loop of results
Do Until rs.EOF = True

  
'Create Email
' настройки письма для пользователя
Set objEmail = CreateObject("CDO.Message")
objEmail.From = "[email protected]"
objEmail.To = rs.Fields("mail")
'Optional BCC field
'objEmail.BCC = "[email protected]"
objEmail.Subject = "A welcome message from Exchange"
objEmail.HTMLbody = "Добро пожаловать в ........."
  
objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/languagecode") = 1049
'objMessage.BodyPart.CharSet = "windows-1251".
objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/usemessageresponsetext") = true
'Optional Add an attachment
'objEmail.AddAttachment "C:\new_hire_audio_message.wav"

objEmail.Configuration.Fields.Item _
    ("http://schemas.microsoft.com/cdo/configuration/sendusing  ") = 2
objEmail.Configuration.Fields.Item _
    ("http://schemas.microsoft.com/cdo/configuration/smtpserver  ") = _
        "ExchangeServer" 'Replace ExchangeServer with server IP or name
objEmail.Configuration.Fields.Item _
    ("http://schemas.microsoft.com/cdo/configuration/smtpserverport  ") = 25
objEmail.Configuration.Fields.Update
  
'Optional - Read the message before it's sent
'MsgBox objEmail.GetStream.ReadText
objEmail.Send
rs.movenext
Loop
  
'Close AD Connection
oConnection1.close

лише одна трабла - мені не вдалося подружити його з кирилицею

Буду дуже вдячний якщо хтось пофіксить це!

Пробуй

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

'Created by Mike Ruman 8/13/05
'Sends an email to accounts created today.

Dim StrDate, CurrentUTC

'Create the current date and time stamp for query for day before last
CurrentUTC = DatePart("yyyy", Date)
'now add Month in mm if only M add leading 0
if DatePart("m" , Now) < 10 then
CurrentUTC = CurrentUTC & 0 & DatePart("m" , Now)
else
CurrentUTC = CurrentUTC & DatePart("m" , Now)
end if
'now add Day in dd if only d add leading 0
if DatePart("d" , Now) < 10 then
'OPTIONAL - FOR MANY DAYS, replace line below with CurrentUTC = CurrentUTC & 0 & DatePart("d" , Now - X) where X = # of days

CurrentUTC = CurrentUTC & 0 & DatePart("d" , Now)
else
'OPTIONAL - FOR MANY DAYS, replace line below with CurrentUTC = CurrentUTC & DatePart("d" , Now - X) where X = # of days
CurrentUTC = CurrentUTC & DatePart("d" , Now)
end if
' Tag hour, minute, second on
strDate = CurrentUTC&"000001.0Z"

'Create AD Connection
Set oConnection1 = CreateObject("ADODB.Connection")
Set oCommand1 = CreateObject("ADODB.Command")
oConnection1.Provider = "ADsDSOObject" ' This is the ADSI OLE-DB provider name
oConnection1.Open "Active Directory Provider"
' Create a command object for this connection.
Set oCommand1.ActiveConnection = oConnection1
'Set Query definition
' тут задаем доменные параметры берем из AD
oCommand1.CommandText = "select mail from 'LDAP://DC=it, DC=local' WHERE objectCategory='Person' AND objectClass='user'AND msExchHideFromAddressLists<>'True' AND whenCreated>='" & strDate & "'"

oCommand1.Properties("Page Size") = 30000
' Execute the query.
Set rs = oCommand1.Execute


rs.movefirst
'Create the loop of results
Do Until rs.EOF = True


'Create Email
' настройки письма для пользователя
Set objEmail = CreateObject("CDO.Message")
objEmail.From = "[email protected]"
objEmail.To = rs.Fields("mail")
'Optional BCC field
'objEmail.BCC = "[email protected]"
objMessage.BodyPart.CharSet = "windows-1251"
objEmail.Subject = "A welcome message from Exchange"
objEmail.Textbody = "Добро пожаловать в ........."
'Optional Add an attachment
'objEmail.AddAttachment "C:\new_hire_audio_message.wav"
objEmail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
objEmail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserver") = _
"ExchangeServer" 'Replace ExchangeServer with server IP or name
objEmail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
objEmail.Configuration.Fields.Update
'Optional - Read the message before it's sent
'MsgBox objEmail.GetStream.ReadText
objEmail.Send
rs.movenext
Loop

'Close AD Connection
oConnection1.close

у меня вот это работает на моем Exchange

» Нажмите, чтобы показать спойлер - нажмите опять, чтобы скрыть... «

Set objEmail = CreateObject("CDO.Message")
objEmail.From = "[email protected]"
objEmail.To = "[email protected]"
objEmail.BodyPart.Charset="windows-1251"
objEmail.Subject = "Тестовое сообщение"
objEmail.Textbody = "Проверка кодировки и букв і ъ ї є"
objEmail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
objEmail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserver") = _
"127.0.0.1"
objEmail.Configuration.Fields.Item _
("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
objEmail.Configuration.Fields.Update
objEmail.Send

Сообщение отредактировал Alex_GR - Jun 19 2008, 18:07

[Fanta]

Странно але в мене матюкаеться на
objMessage.BodyPart.CharSet = "windows-1251"

Зберігав в різних кодіровках але результат той самий

[Alex_GR]

Странно але в мене матюкаеться на
objMessage.BodyPart.CharSet = "windows-1251"

Зберігав в різних кодіровках але результат той самий

Так при сохранении файла хоть русские буквы видно ? Или крякозяблы ?
Пробуй на других машинках..................

А у тебя что установлено в "Языки и региональные стандарты" на вкладке дополнительно ? У меня - Русский.

1. Пробуй вместо windows-1251 ставить koi8-u или koi8-r

2. У тебя в скрипте была запись - "objEmail.Configuration.Fields.Item("http://schemas.microsoft.com
/cdo/configuration/languagecode") = 1049"
Поставь кодовую страницу 0419 вместо 1049.

[Alex_GR]

"Скрипт Центр" - справочник VBS в примерах от Мелкософта

http://www.freespace.com.ua/file/57099/4e1...ipt_center.html

[Fanta]

А у тебя что установлено в "Языки и региональные стандарты" на вкладке дополнительно ? У меня - Русский.

1. Пробуй вместо windows-1251 ставить koi8-u или koi8-r

2. У тебя в скрипте была запись - "objEmail.Configuration.Fields.Item("http://schemas.microsoft.com
/cdo/configuration/languagecode") = 1049"
Поставь кодовую страницу 0419 вместо 1049.

1) Так Русский
2) пробував різні кодування - ефекту 0
3) аналогічно

Я забив на кодіровку - написав текс на англійській мові
Але з*ясувалася інша трабла - в мене скрипт виконуеться кожну годину. І коли за цю годину не було створено нового юзера то скрипту не подобаеться цей кусок

rs.movefirst
'Create the loop of results
Do Until rs.EOF = True

[nickemail]

Граждани а как через комндную строку открыть розшаренную папку соседнего компа с воодом логина и пароля для доступа?

[metalolom]

Граждани а как через комндную строку открыть розшаренную папку соседнего компа с воодом логина и пароля для доступа?

через "net use" подключать/отключать шару как сетевой диск.

[ramasik]

подскажите как можно добавлять в АД инфу по юзерам типа экспорт/ импорт из файла..?
например такие поля: адрес, страна, номер телефона, мобильный, номер комнаты.

можно ли это сделать? а то запаралися в ручную забивать... а ничего толкового не нашел

[klez]

Да, смотрите в сторону Powershell.
Вот тут много готовых скриптов. Думаю можно будет найти то что Вам нужно(+ внести нужные изменения)
http://www.microsoft.com/technet/scriptcenter/hubs/msh.mspx

[ramasik]

Да, смотрите в сторону Powershell.
Вот тут много готовых скриптов. Думаю можно будет найти то что Вам нужно(+ внести нужные изменения)
http://www.microsoft.com/technet/scriptcenter/hubs/msh.mspx

сенкс -- вот нашел может кому пригодится -- именно то что нужно
http://support.microsoft.com/kb/276440/

ЗЫ осталось с синтаксисом разобраться и проверить на тестовом серваке

[metalolom]

подскажите как можно добавлять в АД инфу по юзерам типа экспорт/ импорт из файла..?
например такие поля: адрес, страна, номер телефона, мобильный, номер комнаты.

можно ли это сделать? а то запаралися в ручную забивать... а ничего толкового не нашел

гугли по словам ldif, csvde это встроеные утилиты, ну можно ещё скрипты писать на WSH/powershell

[I00matolog]

Задача банальна - раскидать всем юзерам на рабочий стол ярлык
Сервер 2008 вынь без домена.
т.е.

copy /y c:\tmp\LINK.lnk C:\Users\$I\Desktop

где $I - это перебор файлика с именами профилей

как это на винде делается?
for $i (cat list.txt)
do
copy /y c:\tmp\LINK.lnk C:\Users\$I\Desktop
done

?